DESCRIPTION = "SIP-based IP phone (console edition)"
HOMEPAGE = "http://www.linphone.org/index.php/eng"
SECTION = "x11/utils"
LICENSE = "GPLv2"

DEPENDS = "intltool libosip2 (>=3.0.3) libexosip2 (>=3.0.3) speex (>=1.1.6) \
           libogg alsa-lib readline"
DEPENDS_${PN} = "liblinphone"
DEPENDS_${PN}c = "liblinphone readline"
DEPENDS_liblinphone = "libmediastreamer libortp-linphone libosip2"
DEPENDS_libmediastreamer = "speex (>=1.1.6) speex-dsp (>=1.1.6) libogg alsa-lib libortp-linphone"

RDEPENDS_${PN} = "liblinphone (2.1.1)"
RDEPENDS_${PN}c = "liblinphone (2.1.1) readline"
RDEPENDS_liblinphone = "libmediastreamer (2.1.1) libortp-linphone (2.1.1) \
                        libosip2 (>=3.0.3) libexosip2 (>=3.0.3)"
RDEPENDS_libmediastreamer = "speex (>=1.1.6) speex-dsp (>=1.1.6) \
                             libogg libasound libortp-linphone (2.1.1)"

PROVIDES += "linphone linphonec liblinphone"

PR = "r0"

SRC_URI = "http://download.savannah.nongnu.org/releases/${PN}/stable/sources/${P}.tar.gz \
           http://download.devbase.at/voip/linphone-2.1.1.patch;patch=1"

S = "${WORKDIR}/${P}"

inherit autotools pkgconfig

export PKG_CONFIG=${STAGING_BINDIR_NATIVE}/pkg-config

EXTRA_OECONF = "--disable-gtk-doc \
                --without-ffmpeg --disable-video --without-sdl \
                --enable-alsa \
                --disable-portaudio \
                --libdir=${libdir}/linphone \
                --with-osip=${STAGING_DIR_HOST}${layout_exec_prefix} \
                --with-readline=${STAGING_DIR_HOST}${layout_exec_prefix} \
                --with-speex=${STAGING_DIR_HOST}${layout_exec_prefix} \
                --disable-truespeech --disable-manual \
                --disable-gtk_ui"

PARALLEL_MAKE = ""

do_install () {
	autotools_do_install
	# move linphone's ortp into its private directory
	mv ${D}/${includedir}/ortp ${D}/${includedir}/linphone/ortp
	# remove some pkgconfig files to avoid conflicts with ortp package
	rm ${D}/${libdir}/linphone/pkgconfig/{mediastreamer,ortp}.pc
	# move pkgconfig directory to correct place
	mv ${D}/${libdir}/linphone/pkgconfig ${D}/${libdir}/pkgconfig
	# don't use the mediastream application for now
	rm -Rf ${D}/${libexecdir}
}

do_stage () {
        install -d ${STAGING_DATADIR}/pkgconfig
        install -m 0644 ${S}/share/linphone.pc ${STAGING_DATADIR}/pkgconfig
        install -d ${STAGING_LIBDIR}/linphone
        oe_libinstall -a -so liblinphone ${STAGING_LIBDIR}/linphone
        install -d ${STAGING_INCDIR}/linphone
        install -m 0644 ${S}/coreapi/linphonecore.h ${STAGING_INCDIR}/linphone
        install -m 0644 ${S}/coreapi/lpconfig.h ${STAGING_INCDIR}/linphone
        oe_libinstall -a -so libmediastreamer ${STAGING_LIBDIR}/linphone
        install -d ${STAGING_INCDIR}/mediastreamer2
        install -m 0644 ${S}/mediastreamer2/include/mediastreamer2/*.h ${STAGING_INCDIR}/mediastreamer2
        # install ortp to linphone-specific include directory
        install -d ${STAGING_INCDIR}/linphone/ortp
        oe_libinstall -a -so libortp ${STAGING_LIBDIR}/linphone
        install -m 0644 ${S}/oRTP/include/ortp/*.h ${STAGING_INCDIR}/linphone/ortp/
}

PACKAGES += " linphonec linphone-rings liblinphone libmediastreamer libortp-linphone"

FILES_${PN} = "${bindir}/linphone ${datadir}/pixmaps ${datadir}/applications ${datadir}/gnome/apps"
FILES_${PN}c = "${bindir}/linphonec ${bindir}/sipomatic ${datadir}/sounds/linphone/ringback.wav"
FILES_${PN}-rings = "${datadir}/sounds/linphone/rings"
FILES_liblinphone = "${libdir}/linphone/liblinphone.so*"
FILES_libmediastreamer = "${libdir}/linphone/libmediastreamer.so*"
FILES_libortp-linphone = "${libdir}/linphone/libortp.so*"
FILES_${PN}-dev += "${libdir}/linphone/*.a ${libdir}/linphone/*.la ${libdir}/pkgconfig ${includedir}"